FM / indent

/usr/share/vim/vim82/indent

Name	Size	Mode	Actions
aap.vim	265	0644	edit dl rm
ada.vim	11235	0644	edit dl rm
ant.vim	290	0644	edit dl rm
automake.vim	243	0644	edit dl rm
awk.vim	7774	0644	edit dl rm
bash.vim	350	0644	edit dl rm
bib.vim	346	0644	edit dl rm
bst.vim	1937	0644	edit dl rm
bzl.vim	2484	0644	edit dl rm
c.vim	325	0644	edit dl rm
cdl.vim	4253	0644	edit dl rm
ch.vim	470	0644	edit dl rm
chaiscript.vim	1138	0644	edit dl rm
changelog.vim	264	0644	edit dl rm
clojure.vim	11668	0644	edit dl rm
cmake.vim	2683	0644	edit dl rm
cobol.vim	8695	0644	edit dl rm
config.vim	2182	0644	edit dl rm
context.vim	752	0644	edit dl rm
cpp.vim	329	0644	edit dl rm
cs.vim	1756	0644	edit dl rm
css.vim	1790	0644	edit dl rm
cucumber.vim	2678	0644	edit dl rm
cuda.vim	305	0644	edit dl rm
d.vim	510	0644	edit dl rm
dictconf.vim	337	0644	edit dl rm
dictdconf.vim	338	0644	edit dl rm
docbk.vim	336	0644	edit dl rm
dosbatch.vim	1335	0644	edit dl rm
dtd.vim	11869	0644	edit dl rm
dtrace.vim	451	0644	edit dl rm
dune.vim	332	0644	edit dl rm
dylan.vim	2707	0644	edit dl rm
eiffel.vim	3317	0644	edit dl rm
elm.vim	3223	0644	edit dl rm
erlang.vim	50066	0644	edit dl rm
eruby.vim	3016	0644	edit dl rm
eterm.vim	668	0644	edit dl rm
falcon.vim	14077	0644	edit dl rm
fortran.vim	7664	0644	edit dl rm
framescript.vim	816	0644	edit dl rm
gitconfig.vim	841	0644	edit dl rm
gitolite.vim	1277	0644	edit dl rm
go.vim	1673	0644	edit dl rm
haml.vim	2203	0644	edit dl rm
hamster.vim	1425	0644	edit dl rm
hog.vim	1892	0644	edit dl rm
html.vim	33539	0644	edit dl rm
htmldjango.vim	273	0644	edit dl rm
idlang.vim	1620	0644	edit dl rm
ishd.vim	1877	0644	edit dl rm
j.vim	1812	0644	edit dl rm
java.vim	4287	0644	edit dl rm
javascript.vim	15362	0644	edit dl rm
javascriptreact.vim	109	0644	edit dl rm
json.vim	4527	0644	edit dl rm
jsp.vim	462	0644	edit dl rm
ld.vim	1792	0644	edit dl rm
less.vim	243	0644	edit dl rm
lifelines.vim	637	0644	edit dl rm
liquid.vim	1899	0644	edit dl rm
lisp.vim	353	0644	edit dl rm
logtalk.vim	1859	0644	edit dl rm
lua.vim	1927	0644	edit dl rm
mail.vim	308	0644	edit dl rm
make.vim	3488	0644	edit dl rm
matlab.vim	4842	0644	edit dl rm
meson.vim	5223	0644	edit dl rm
mf.vim	156	0644	edit dl rm
mma.vim	2235	0644	edit dl rm
mp.vim	11321	0644	edit dl rm
nsis.vim	3257	0644	edit dl rm
objc.vim	1645	0644	edit dl rm
ocaml.vim	9191	0644	edit dl rm
occam.vim	4637	0644	edit dl rm
pascal.vim	5656	0644	edit dl rm
perl.vim	5905	0644	edit dl rm
perl6.vim	3542	0644	edit dl rm
php.vim	25901	0644	edit dl rm
postscr.vim	1649	0644	edit dl rm
pov.vim	2662	0644	edit dl rm
prolog.vim	1804	0644	edit dl rm
pyrex.vim	326	0644	edit dl rm
python.vim	6928	0644	edit dl rm
r.vim	14037	0644	edit dl rm
raml.vim	285	0644	edit dl rm
readline.vim	711	0644	edit dl rm
README.txt	1689	0644	edit dl rm
rhelp.vim	2840	0644	edit dl rm
rmd.vim	1680	0644	edit dl rm
rnoweb.vim	1087	0644	edit dl rm
rpl.vim	1863	0644	edit dl rm
rrst.vim	1195	0644	edit dl rm
rst.vim	1820	0644	edit dl rm
ruby.vim	30119	0644	edit dl rm
rust.vim	6498	0644	edit dl rm
sas.vim	5270	0644	edit dl rm
sass.vim	950	0644	edit dl rm
scala.vim	19430	0644	edit dl rm
scheme.vim	372	0644	edit dl rm
scss.vim	191	0644	edit dl rm
sdl.vim	2794	0644	edit dl rm
sh.vim	9271	0644	edit dl rm
sml.vim	6478	0644	edit dl rm
sql.vim	1204	0644	edit dl rm
sqlanywhere.vim	13426	0644	edit dl rm
sshconfig.vim	796	0644	edit dl rm
systemd.vim	205	0644	edit dl rm
systemverilog.vim	8626	0644	edit dl rm
tcl.vim	2513	0644	edit dl rm
tcsh.vim	1270	0644	edit dl rm
teraterm.vim	1365	0644	edit dl rm
tex.vim	13689	0644	edit dl rm
tf.vim	1549	0644	edit dl rm
tilde.vim	1013	0644	edit dl rm
treetop.vim	707	0644	edit dl rm
typescript.vim	14480	0644	edit dl rm
vb.vim	2089	0644	edit dl rm
verilog.vim	8165	0644	edit dl rm
vhdl.vim	14666	0644	edit dl rm
vim.vim	5702	0644	edit dl rm
vroom.vim	379	0644	edit dl rm
wast.vim	458	0644	edit dl rm
xf86conf.vim	709	0644	edit dl rm
xhtml.vim	269	0644	edit dl rm
xinetd.vim	1231	0644	edit dl rm
xml.vim	7604	0644	edit dl rm
xsd.vim	253	0644	edit dl rm
xslt.vim	297	0644	edit dl rm
yacc.vim	781	0644	edit dl rm
yaml.vim	5471	0644	edit dl rm
zimbu.vim	3936	0644	edit dl rm
zsh.vim	411	0644	edit dl rm

Edit: /usr/share/vim/vim82/indent/clojure.vim (11668B)

" Vim indent file
" Language:           Clojure
" Maintainer:         Alex Vear <av@axvr.io>
" Former Maintainers: Sung Pae <self@sungpae.com>
"                     Meikel Brandmeyer <mb@kotka.de>
" URL:                https://github.com/clojure-vim/clojure.vim
" License:            Vim (see :h license)
" Last Change:        2021-02-13

if exists("b:did_indent")
	finish
endif
let b:did_indent = 1

let s:save_cpo = &cpo
set cpo&vim

let b:undo_indent = 'setlocal autoindent< smartindent< expandtab< softtabstop< shiftwidth< indentexpr< indentkeys<'

setlocal noautoindent nosmartindent
setlocal softtabstop=2 shiftwidth=2 expandtab
setlocal indentkeys=!,o,O

if exists("*searchpairpos")

if !exists('g:clojure_maxlines')
		let g:clojure_maxlines = 100
	endif

if !exists('g:clojure_fuzzy_indent')
		let g:clojure_fuzzy_indent = 1
	endif

if !exists('g:clojure_fuzzy_indent_patterns')
		let g:clojure_fuzzy_indent_patterns = ['^with', '^def', '^let']
	endif

if !exists('g:clojure_fuzzy_indent_blacklist')
		let g:clojure_fuzzy_indent_blacklist = ['-fn$', '\v^with-%(meta|out-str|loading-context)$']
	endif

if !exists('g:clojure_special_indent_words')
		let g:clojure_special_indent_words = 'deftype,defrecord,reify,proxy,extend-type,extend-protocol,letfn'
	endif

if !exists('g:clojure_align_multiline_strings')
		let g:clojure_align_multiline_strings = 0
	endif

if !exists('g:clojure_align_subforms')
		let g:clojure_align_subforms = 0
	endif

function! s:syn_id_name()
		return synIDattr(synID(line("."), col("."), 0), "name")
	endfunction

function! s:ignored_region()
		return s:syn_id_name() =~? '\vstring|regex|comment|character'
	endfunction

function! s:current_char()
		return getline('.')[col('.')-1]
	endfunction

function! s:current_word()
		return getline('.')[col('.')-1 : searchpos('\v>', 'n', line('.'))[1]-2]
	endfunction

function! s:is_paren()
		return s:current_char() =~# '\v[\[\]\{\}]' && !s:ignored_region()
	endfunction

" Returns 1 if string matches a pattern in 'patterns', which may be a
	" list of patterns, or a comma-delimited string of implicitly anchored
	" patterns.
	function! s:match_one(patterns, string)
		let list = type(a:patterns) == type([])
		           \ ? a:patterns
		           \ : map(split(a:patterns, ','), '"^" . v:val . "$"')
		for pat in list
			if a:string =~# pat | return 1 | endif
		endfor
	endfunction

function! s:match_pairs(open, close, stopat)
		" Stop only on vector and map [ resp. {. Ignore the ones in strings and
		" comments.
		if a:stopat == 0 && g:clojure_maxlines > 0
			let stopat = max([line(".") - g:clojure_maxlines, 0])
		else
			let stopat = a:stopat
		endif

let pos = searchpairpos(a:open, '', a:close, 'bWn', "!s:is_paren()", stopat)
		return [pos[0], col(pos)]
	endfunction

function! s:clojure_check_for_string_worker()
		" Check whether there is the last character of the previous line is
		" highlighted as a string. If so, we check whether it's a ". In this
		" case we have to check also the previous character. The " might be the
		" closing one. In case the we are still in the string, we search for the
		" opening ". If this is not found we take the indent of the line.
		let nb = prevnonblank(v:lnum - 1)

if nb == 0
			return -1
		endif

call cursor(nb, 0)
		call cursor(0, col("$") - 1)
		if s:syn_id_name() !~? "string"
			return -1
		endif

" This will not work for a " in the first column...
		if s:current_char() == '"'
			call cursor(0, col("$") - 2)
			if s:syn_id_name() !~? "string"
				return -1
			endif
			if s:current_char() != '\'
				return -1
			endif
			call cursor(0, col("$") - 1)
		endif

let p = searchpos('$^\|[^\\]$\zs"', 'bW')

if p != [0, 0]
			return p[1] - 1
		endif

return indent(".")
	endfunction

function! s:check_for_string()
		let pos = getpos('.')
		try
			let val = s:clojure_check_for_string_worker()
		finally
			call setpos('.', pos)
		endtry
		return val
	endfunction

function! s:strip_namespace_and_macro_chars(word)
		return substitute(a:word, "\\v%(.*/|[#'`~@^,]*)(.*)", '\1', '')
	endfunction

function! s:clojure_is_method_special_case_worker(position)
		" Find the next enclosing form.
		call search('\S', 'Wb')

" Special case: we are at a '(('.
		if s:current_char() == '('
			return 0
		endif
		call cursor(a:position)

let next_paren = s:match_pairs('(', ')', 0)

" Special case: we are now at toplevel.
		if next_paren == [0, 0]
			return 0
		endif
		call cursor(next_paren)

call search('\S', 'W')
		let w = s:strip_namespace_and_macro_chars(s:current_word())

if g:clojure_special_indent_words =~# '\V\<' . w . '\>'

" `letfn` is a special-special-case.
			if w ==# 'letfn'
				" Earlier code left the cursor at:
				"     (letfn [...] ...)
				"      ^

" Search and get coordinates of first `[`
				"     (letfn [...] ...)
				"            ^
				call search('\[', 'W')
				let pos = getcurpos()
				let letfn_bracket = [pos[1], pos[2]]

" Move cursor to start of the form this function was
				" initially called on.  Grab the coordinates of the
				" closest outer `[`.
				call cursor(a:position)
				let outer_bracket = s:match_pairs('\[', '\]', 0)

" If the located square brackets are not the same,
				" don't use special-case formatting.
				if outer_bracket != letfn_bracket
					return 0
				endif
			endif

return 1
		endif

return 0
	endfunction

function! s:is_method_special_case(position)
		let pos = getpos('.')
		try
			let val = s:clojure_is_method_special_case_worker(a:position)
		finally
			call setpos('.', pos)
		endtry
		return val
	endfunction

" Check if form is a reader conditional, that is, it is prefixed by #?
	" or @#?
	function! s:is_reader_conditional_special_case(position)
		return getline(a:position[0])[a:position[1] - 3 : a:position[1] - 2] == "#?"
	endfunction

" Returns 1 for opening brackets, -1 for _anything else_.
	function! s:bracket_type(char)
		return stridx('([{', a:char) > -1 ? 1 : -1
	endfunction

" Returns: [opening-bracket-lnum, indent]
	function! s:clojure_indent_pos()
		" Get rid of special case.
		if line(".") == 1
			return [0, 0]
		endif

" We have to apply some heuristics here to figure out, whether to use
		" normal lisp indenting or not.
		let i = s:check_for_string()
		if i > -1
			return [0, i + !!g:clojure_align_multiline_strings]
		endif

call cursor(0, 1)

" Find the next enclosing [ or {. We can limit the second search
		" to the line, where the [ was found. If no [ was there this is
		" zero and we search for an enclosing {.
		let paren = s:match_pairs('(', ')', 0)
		let bracket = s:match_pairs('\[', '\]', paren[0])
		let curly = s:match_pairs('{', '}', bracket[0])

" In case the curly brace is on a line later then the [ or - in
		" case they are on the same line - in a higher column, we take the
		" curly indent.
		if curly[0] > bracket[0] || curly[1] > bracket[1]
			if curly[0] > paren[0] || curly[1] > paren[1]
				return curly
			endif
		endif

" If the curly was not chosen, we take the bracket indent - if
		" there was one.
		if bracket[0] > paren[0] || bracket[1] > paren[1]
			return bracket
		endif

" There are neither { nor [ nor (, ie. we are at the toplevel.
		if paren == [0, 0]
			return paren
		endif

" Now we have to reimplement lispindent. This is surprisingly easy, as
		" soon as one has access to syntax items.
		"
		" - Check whether we are in a special position after a word in
		"   g:clojure_special_indent_words. These are special cases.
		" - Get the next keyword after the (.
		" - If its first character is also a (, we have another sexp and align
		"   one column to the right of the unmatched (.
		" - In case it is in lispwords, we indent the next line to the column of
		"   the ( + sw.
		" - If not, we check whether it is last word in the line. In that case
		"   we again use ( + sw for indent.
		" - In any other case we use the column of the end of the word + 2.
		call cursor(paren)

if s:is_method_special_case(paren)
			return [paren[0], paren[1] + &shiftwidth - 1]
		endif

if s:is_reader_conditional_special_case(paren)
			return paren
		endif

" In case we are at the last character, we use the paren position.
		if col("$") - 1 == paren[1]
			return paren
		endif

" In case after the paren is a whitespace, we search for the next word.
		call cursor(0, col('.') + 1)
		if s:current_char() == ' '
			call search('\v\S', 'W')
		endif

" If we moved to another line, there is no word after the (. We
		" use the ( position for indent.
		if line(".") > paren[0]
			return paren
		endif

" We still have to check, whether the keyword starts with a (, [ or {.
		" In that case we use the ( position for indent.
		let w = s:current_word()
		if s:bracket_type(w[0]) == 1
			return paren
		endif

" If the keyword begins with #, check if it is an anonymous
		" function or set, in which case we indent by the shiftwidth
		" (minus one if g:clojure_align_subforms = 1), or if it is
		" ignored, in which case we use the ( position for indent.
		if w[0] == "#"
			" TODO: Handle #=() and other rare reader invocations?
			if w[1] == '(' || w[1] == '{'
				return [paren[0], paren[1] + (g:clojure_align_subforms ? 0 : &shiftwidth - 1)]
			elseif w[1] == '_'
				return paren
			endif
		endif

" Test words without namespace qualifiers and leading reader macro
		" metacharacters.
		"
		" e.g. clojure.core/defn and #'defn should both indent like defn.
		let ww = s:strip_namespace_and_macro_chars(w)

if &lispwords =~# '\V\<' . ww . '\>'
			return [paren[0], paren[1] + &shiftwidth - 1]
		endif

if g:clojure_fuzzy_indent
			\ && !s:match_one(g:clojure_fuzzy_indent_blacklist, ww)
			\ && s:match_one(g:clojure_fuzzy_indent_patterns, ww)
			return [paren[0], paren[1] + &shiftwidth - 1]
		endif

call search('\v\_s', 'cW')
		call search('\v\S', 'W')
		if paren[0] < line(".")
			return [paren[0], paren[1] + (g:clojure_align_subforms ? 0 : &shiftwidth - 1)]
		endif

call search('\v\S', 'bW')
		return [line('.'), col('.') + 1]
	endfunction

function! GetClojureIndent()
		let lnum = line('.')
		let orig_lnum = lnum
		let orig_col = col('.')
		let [opening_lnum, indent] = s:clojure_indent_pos()

" Account for multibyte characters
		if opening_lnum > 0
			let indent -= indent - virtcol([opening_lnum, indent])
		endif

" Return if there are no previous lines to inherit from
		if opening_lnum < 1 || opening_lnum >= lnum - 1
			call cursor(orig_lnum, orig_col)
			return indent
		endif

let bracket_count = 0

" Take the indent of the first previous non-white line that is
		" at the same sexp level. cf. src/misc1.c:get_lisp_indent()
		while 1
			let lnum = prevnonblank(lnum - 1)
			let col = 1

if lnum <= opening_lnum
				break
			endif

call cursor(lnum, col)

" Handle bracket counting edge case
			if s:is_paren()
				let bracket_count += s:bracket_type(s:current_char())
			endif

while 1
				if search('\v[(\[{}\])]', '', lnum) < 1
					break
				elseif !s:ignored_region()
					let bracket_count += s:bracket_type(s:current_char())
				endif
			endwhile

if bracket_count == 0
				" Check if this is part of a multiline string
				call cursor(lnum, 1)
				if s:syn_id_name() !~? '\vstring|regex'
					call cursor(orig_lnum, orig_col)
					return indent(lnum)
				endif
			endif
		endwhile

call cursor(orig_lnum, orig_col)
		return indent
	endfunction

setlocal indentexpr=GetClojureIndent()

else

" In case we have searchpairpos not available we fall back to
	" normal lisp indenting.
	setlocal indentexpr=
	setlocal lisp
	let b:undo_indent .= '| setlocal lisp<'

endif

let &cpo = s:save_cpo
unlet! s:save_cpo

" vim:sts=8:sw=8:ts=8:noet

cmd: